***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Feb 18, 2025                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt P6SMB12A  A K 
.param
+vc0 = 9.746e-10	       vc1 = 7.816e-10	       vc2 = 1.000		 vc3 = 2.803e-10		 vc4 = 4.835e-1
+tc1 = 3.008e-2		 tc2 = 1.995e-2		 tc3 = 3.008e-2		 tc4 = 1.995e-2	   
.func irexp(v) {(vc0+vc1*v**vc2)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc3*exp(vc4*v))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
.func rbv(i) {3.937e-2*min(i,0)}
d1 A A1 zener
g1 A1 A value = {irexp(v(A1,A))}
v1 A1 K1 0
e1 K1 K value = {rbv(i(v1))}
.model zener d
***** flag parameter *****
+level = 1 
***** dc model parameter *****
+ is = 3.163e-13	       n = 1.087         rs = 1.383e-2
+ibv = 1.0e-3		 nbv = 1.400	  bv = 12
+ikf = 3.224
***** capacitance parameter *****
+cjo = 2.585e-9	   m = 2.564e-1		  vj = 3.905e-1
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		      eg = 1.050		      xti = 3
+trs1=-1.840e-3         tikf=-1.455e-3       
+tbv1 = 6.157e-4	      tbv2 = -1.529e-7
.ends P6SMB12A
*$
